Arduino

Arduino String/Dizi Nesne Oluşturucuları

Yazar

2018-05-08

2710

Okunma

Arduino String/Dizi Nesne Oluşturucuları

Arduino String/Dizi Nesne Oluşturucuları. String nesnesi , metin dizelerini çeşitli yararlı yollarla işlemenizi sağlar. Karakterleri Dizelere ekleyebilir, Dizeleri birleştirerek birleştirebilir, Dizenin uzunluğunu alabilir, alt dizeleri arayabilir ve değiştirebilir ve daha fazlasını yapabilirsiniz. Bu eğitici, String nesnelerini nasıl başlatacağınızı gösterir.

String stringOne = "Merhaba String";                    // sabit bir String kullanarak
String stringOne =  String('a');                        // sabit bir karakter dizisini bir dizeye dönüştürme
String stringTwo =  String("Bu bir string");            // sabit bir dizeyi bir String nesnesine dönüştürmek
String stringOne =  String(stringTwo + " daha fazla");  // iki dizenin birleştirilmesi
String stringOne =  String(13);                         // sabit bir tamsayı kullanarak
String stringOne =  String(analogRead(0), DEC);         // int ve taban kullanarak
String stringOne =  String(45, HEX);                    // int ve (onaltılı) taban kullanarak
String stringOne =  String(255, BIN);                   // int ve (binary) taban kullanarak
String stringOne =  String(millis(), DEC);              // uzun ve üssü kullanarak
String stringOne =  String(5.698, 3);                   // bir float ve ondalık basamaklar kullanarak

Tüm bu yöntemler, bir String nesnesini bildirmenin geçerli yoludur. Hepsi, String yöntemlerinden herhangi biri kullanılarak işlenebilen bir karakter dizisi içeren bir nesneye neden olur. Bunları hareket halinde görmek için, aşağıdaki kodu Arduino veya Genuino kartına yükleyin ve Arduino IDE seri monitörünü açın. Her bir beyanın sonuçlarını göreceksiniz. Her println() tarafından basılanları, üstündeki beyanla karşılaştırın.

Donanım

Arduino veya Genuino

“Arduino Uno, ATmega328P tabanlı bir mikro denetleyici karttır. 14 adet dijital giriş / çıkış pini (6’sı PWM çıkışı olarak kullanılabilir), 6 analog giriş, 16 MHz kristali, bir USB bağlantısı, bir güç girişi, bir ICSP başlığı ve bir sıfırlama düğmesi vardır. Mikrodenetleyiciyi desteklemek için gereken her şeyi içerir; Başlamak için bir USB kablosuyla bir bilgisayara bağlayın ya da AC-DC adaptörü ya da pille çalıştırın. UNO’yu, yanlış bir şey yapmadan çok fazla endişe etmeden tamir edebilir, en kötü durum senaryosunu değiştirebilirsiniz. Birkaç dolara çip alır ve tekrar kullanabilirsiniz.”

Devre

Bu örnek için devre yoktur, kartınızın USB üzerinden bilgisayara bağlı olması ve Arduino Yazılımının (IDE) seri monitör penceresi açık olmalıdır.

Kod

/*
String kurucular

Diğer veri türlerinden Dizelerin nasıl oluşturulacağına dair örnekler

oluşturuldu 27 Tem 2010
değiştirildi 30 Ağu 2011
Tom Igoe tarafından

Bu örnek kod kamu malıdır.
http://www.arduino.cc/en/Tutorial/StringConstructors
*/

void setup() {
  // Seri haberleşmeyi açın ve bağlantı noktasının açılmasını bekleyin:
  Serial.begin(9600);
  while (!Serial) {
    ; // bağlanmak için seri portu bekleyin. Sadece yerel USB bağlantı noktası için gerekli
  }

  // bir giriş gönderin:
  Serial.println("\n\nString/Dizi Oluşturucular:");
  Serial.println();
}

void loop() {
  // sabit bir Dize kullanarak:
  String stringOne = "Merhaba String";
  Serial.println(stringOne);      // "Merhaba String" yazdırır

  // sabit bir karakterin bir String'e dönüştürülmesi:
  stringOne =  String('a');
  Serial.println(stringOne);       // "a" yazdırır

  // sabit bir dizeyi bir String nesnesine dönüştürmek:
  String stringTwo =  String("Bu bir string");
  Serial.println(stringTwo);      // "Bu bir string" yazdırır

 // iki dizenin birleştirilmesi:
  stringOne =  String(stringTwo + " daha fazla");
  // "Bu daha fazla bir String" yazdırır:
  Serial.println(stringOne);

 // sabit bir tamsayı kullanarak:
  stringOne =  String(13);
  Serial.println(stringOne);      // "13" yazdırır

  // int ve taban kullanarak:
  stringOne =  String(analogRead(A0), DEC);
  // "453" veya analogRead(A0) ne var ise yazdırır 
  Serial.println(stringOne);

  / int ve (onaltılık) taban kullanarak:
  stringOne =  String(45, HEX);
  // ondalık 45'in onaltılık sürümü olan "2d" yi yazdırır:
  Serial.println(stringOne);

  // int ve (binary) taban kullanarak
  stringOne =  String(255, BIN);
 // 255'in ikili değeri olan "11111111" yazdırır
  Serial.println(stringOne);

  // uzun ve üssü kullanarak:
  stringOne =  String(millis(), DEC);
  // "123456" yazdırır veya millis() değeri ne olursa:
  Serial.println(stringOne);

  // bir kayan nokta ve doğru ondalık basamaklar kullanarak:
  stringOne = String(5.698, 3);
  Serial.println(stringOne);

  // yuvarlamayı kullanmak için bir kayan nokta ve daha az ondalık basamak kullanarak:
  stringOne = String(5.698, 2);
  Serial.println(stringOne);

  // true iken hiçbir şey yapmayın:
  while (true);

}

Kaynak:arduino.cc