Arduino Klavye Programlama Uygulaması

0
2265
Okunma

Arduino Klavye Programlama Uygulaması

Arduino Klavye Programlama Uygulaması

Arduino Klavye Programlama Uygulaması. Bu örnekte yeni bir Arduino Yazılımı (IDE) çizim penceresi açmak, Blink örneğinde yazan klavye komutlarını göndermek ve kartı yeniden programlamak için Klavye kitaplığını kullanır. Bu çizimi çalıştırdıktan ve düğme 2’yi basma butonu kullanarak topladıktan sonra, panonun yeni bir programı olacak, Blink.

Not: Keyboard.print() komutunu kullandığınızda, Arduino bilgisayarınızın klavyesini ele geçirir! Bu işlevle bir eskiz çalışırken, bilgisayarınızın kontrolünü kaybetmemenizi garantilemek için, Keyboard.print () öğesini çağırmadan önce güvenilir bir kontrol sistemi kurduğunuzdan emin olun. Bu taslak, dijital pin 2 toprağa çekildikten sonra sadece Klavye komutları göndermek için tasarlanmıştır.

Arduino Klavye Programlama Uygulaması

Donanım

“Arduino Leonardo, ATmega32u4 tabanlı bir mikrodenetleyici karttır. 20 adet dijital giriş / çıkış pini (bunların 7 tanesi PWM çıkışı ve 12’si analog giriş olarak kullanılabilir), 16 MHz kristal osilatör, mikro USB bağlantısı, bir güç girişi, bir ICSP başlığı ve bir sıfırlama düğmesine sahiptir. Mikrodenetleyiciyi desteklemek için gereken her şeyi içerir; Başlamak için bir USB kablosuyla bir bilgisayara bağlayın ya da AC-DC adaptörü veya batarya ile çalıştırın.

Leonardo, ATmega32u4’ün dahili bir USB iletişimine sahip olduğu ve ikincil bir işlemci ihtiyacını ortadan kaldıran önceki tüm panolardan farklıdır. Bu, Leonardo’nun bir sanal (CDC) seri / COM portuna ek olarak bağlı bir bilgisayara fare ve klavye olarak görünmesini sağlar.

Gerekli Yazılım

  • Arduino IDE hazırda açık bulunmalıdır.

Kod

Kartınızı USB bağlantı noktasına bağlayın, ardından D2’yi GND ile bağlamak için düğmeye basın ve eskiz klavyesi tuşa basma emülasyonunu başlatın. Düğmeye basmadan önce Arduino Yazılım (IDE) penceresinin seçili olduğunu unutmayın.

/*
Arduino Programları Blink

Bu taslak Klavye kütüphanesini göstermektedir.

Sadece Leonardo ve Due kurulları için.

Pin 2'yi toprağa bağladığınızda, anahtarla yeni bir pencere oluşturur.
kombinasyonu (CTRL-N), ardından Blink çiziminde türleri, sonra otomatik formatları
Başka bir tuş bileşimini kullanarak metin (CTRL-T), daha sonra çizimi
Şu anda bir son tuş kombinasyonu (CTRL-U) kullanarak Arduino seçildi.

Devre:
- Arduino Leonardo, Micro, Due, LilyPad USB veya Yún
- D2'yi toprağa bağlamak için kablo

5 Mar 2012 tarihinde oluşturuldu
modifiye 29 Mar 2012
Tom Igoe tarafından
3 Mayıs 2014'te değiştirildi
ile Scott Fitzgerald

Bu örnek kamu malıdır.
http://www.arduino.cc/en/Tutorial/KeyboardReprogram
*/

#include "Keyboard.h"

// OSX için bu seçeneği kullanın.
// Windows veya Linux kullanıyorsa yorumlayın:
char ctrlKey = KEY_LEFT_GUI;
// Windows ve Linux için bu seçeneği kullanın.
// OSX kullanılıyorsa yorum yapılmadı:
// char ctrlKey = KEY_LEFT_CTRL;

void setup() {
  // Pin 2'yi bir giriş yapın ve çekme direncini açın;
  // toprağa(GND) bağlı:
  pinMode(2, INPUT_PULLUP);
  // klavyenin üzerinde denetimi başlat:
  Keyboard.begin();
}

void loop() {
  while (digitalRead(2) == HIGH) {
    // 2 no'lu seviye düşük olana kadar hiçbir şey yapmayın
    delay(500);
  }
  delay(1000);
  // yeni belge:
  Keyboard.press(ctrlKey);
  Keyboard.press('n');
  delay(100);
  Keyboard.releaseAll();
  // açmak için yeni pencere bekleyin:
  delay(1000);

  // Arduino IDE'nin 1.5 sürümleri ile önizlemeli yeni skeçler
  // setup() ve loop() işlevleri, yeni bir şey yazmadan önce pencereyi temizleyelim
  // hepsini seç
  Keyboard.press(ctrlKey);
  Keyboard.press('a');
  delay(500);
  Keyboard.releaseAll();
  // seçilen metni sil
  Keyboard.write(KEY_BACKSPACE);
  delay(500);

  // "Göz kırp(Blink) programını yazın" yazın:
  Keyboard.println("void setup() {");
  Keyboard.println("pinMode(13, OUTPUT);");
  Keyboard.println("}");
  Keyboard.println();
  Keyboard.println("void loop() {");
  Keyboard.println("digitalWrite(13, HIGH);");
  Keyboard.print("delay(3000);");
  // 3000 ms çok uzun. Silin:
  for (int keystrokes = 0; keystrokes < 6; keystrokes++) {
    delay(500);
    Keyboard.write(KEY_BACKSPACE);
  }
  // yerine 1000 yapın:
  Keyboard.println("1000);");
  Keyboard.println("digitalWrite(13, LOW);");
  Keyboard.println("delay(1000);");
  Keyboard.println("}");
  // toparlamak:
  Keyboard.press(ctrlKey);
  Keyboard.press('t');
  delay(100);
  Keyboard.releaseAll();
  delay(3000);
  // Kodu Yükle:
  Keyboard.press(ctrlKey);
  Keyboard.press('u');
  delay(100);
  Keyboard.releaseAll();

  // yeniden programlamayı bekleyin:
  while (true);
}

Kaynak:arduino.cc

CEVAP VER

Please enter your comment!
Please enter your name here

This site uses Akismet to reduce spam. Learn how your comment data is processed.